$Title Soft Suds Brewing and Bottling Company problem

$ontext
The Soft Suds Brewing and Bottling Company, because of faulty
planning, was not prepared for the UW Comp Sci Department.  There was
to be a big party in Madison and Gus Guzzler, the manager, knew that
Soft Suds would be called upon to supply the refreshments.  However
the raw materials required had not been ordered and could not be
obtained before the party.  Gus took an inventory of the available
supplies and found the following:

\begin{verbatim}
Malt    90 units
Hops    40 units
Yeast   80 units
\end{verbatim}

Soft Suds produces two types of pick-me-ups: light beer and dark
beer, with the following specifications:

\begin{tabular}{l|rrr}
           & Malt & Hops & Yeast \\ \hline
Light Beer &    2 &    3 &     2 \\
Dark Beer  &    3 &    1 &   5/3
\end{tabular}

Note that fractions (such as 5/3) may not be entered directly but must
be approximated, or calculated in an assignment.
The light beer brings \$2.00/gallon profit, the dark beer \$1.00/gallon
profit.  Assuming that Comp Sci students will buy whatever is made,
formulate the linear program Gus must solve to maximize profits, and
solve it using GAMS.
$offtext

set ingred "ingredients needed in beer" /malt,hops,yeast/;
set beers "types of beer produced" /light,dark/;

table require (beers,ingred)
	malt	hops	yeast
light	2	3	2
dark	3	1	1.66666666;

parameter price(beers) "in dollars/gallon" /
light	2
dark	1 /;

parameter supply(ingred) "in units" /
malt	90
hops	40
yeast	80 /;

positive variables quant(beers);
variables profit;

equations obj, used(ingred);

obj..
  profit =e= sum(beers,price(beers)*quant(beers));

used(ingred)..
  sum(beers,quant(beers)*require(beers,ingred)) =l= supply(ingred);

model softsuds /all/;

solve softsuds using lp maximizing profit;