#
# This file (.cshrc) is read by each new instantiation of csh or tcsh
#
# There are comments to explain most of what is done
#
# $Id: .cshrc,v 1.35 1999/06/30 14:56:13 thomas Exp $
#
# To make the file writable so you can make changes, you need 
# to use the "chmod" command to change the file permissions to
# the following.  Use the command "man chmod" to find out how.
#
# -rwxr-xr-x   1 myname      3481 Jul 23 13:43 .cshrc

# We check here to see if we're running on Windows NT.  We set the
# 's' environment variable to what the correct prefix should be, and
# for NT set some useful key bindings
if ($?OS) then
	if($OS == "Windows_NT") then
		setenv s s:
		bindkey -b N-up	up-history
		bindkey -b N-down down-history
		bindkey -b N-right forward-char
		bindkey -b N-left backward-char
		bindkey -b N-del delete-char
		bindkey -b N-ins overwrite-mode
		bindkey -b N-1 which-command
		bindkey -b N-2 expand-history
		bindkey -b N-3 complete-word-raw
		bindkey -b N-home beginning-of-line
		bindkey -b N-end end-of-line
	endif
else
	setenv s /s
endif


# Your path is the order of the directories in which your shell looks 
# for programs.  
#
# Software is now being installed in /s/package-name. To use a
# particular pacakge, put /s/package-name/bin in your path (in most
# cases).
# 
# the "std" package has most of the software from /s, so /s/std/bin will
# probably give you everything you want.
#
# /s/std/bin is BEFORE the common unix directory so that the improved
# versions of the standard software are used. If you want the vendor
# versions, either move /s/std/bin after /bin, /usr/bin, /usr/ucb, or
# use aliases or symlinks in your ~/bin.

#
# Set the path here:
# MAKE CHANGES IN ~/.cshrc.local
#
set path = ()				# initialization (DO NOT REMOVE)
set path = ( $path ~/bin )
#set path = ($path $s/gcc-2.95.1/bin)# your bin
set path = ( $path $s/std/bin )		# "standard" lab supported software

# Set some useful paths on our UNIX platforms
if($s == "/s") then
  set path = ( $path /u/g/o/gokul)	# AFS software
  set path = ( $path /usr/afsws/bin )	# AFS software
  set path = ( $path /opt/SUNWspro/bin )	# compilers (on Solaris)
  set path = ( $path /usr/ccs/bin )	# programming tools (on Solaris)
  set path = ( $path /usr/ucb )		# standard programs
  set path = ( $path /bin )		# standard programs
  set path = ( $path /usr/bin )		# standard programs
  set path = ( $path /usr/stat/bin )	# statistics department programs
  set path = ( $path /usr/X11R6/bin )	# X software for linux
  set path = ( $path /unsup/xpdf-0.7b/bin)  
else
  set path = ( $path c:/winnt/system32 ) # NT System Files
  set path = ( $path c:/winnt )		 # NT System Files
  set path = ( $path c:/progra~1/transarc/afs/afsclient/program ) # AFS Software
endif
	
# remove domain name (.cs.wisc.edu in our case) from hostname, if
# domain name is in hostname (otherwise, just hostname).
setenv HOSTNAME `hostname | sed -e s/\\..\*//`


# determine our machine/cpu type and operating system type
if ($s == "/s") then
  setenv CPUTYPE `hostinfo -m`
  setenv OSTYPE `hostinfo -o`
else
  if ($?OS) then
	if ($OS == "Windows_NT") then
		setenv CPUTYPE $PROCESSOR_ARCHITECTURE
		setenv OSTYPE $OS
	endif
  endif
endif

# if on a system that doesn't define USER by default, set it here so
# that we don't have to test for it every time
if ( ! $?USER ) then
    setenv USER ${LOGNAME}
endif    

# get users's personal aliases, etc
if ( -f ~/.cshrc.local ) source ~/.cshrc.local