$title Winston and Albright, Example 3.3 (page 88): Drugco Production Process Model

set drugs /A,B,C/;

scalar labor "total amount of labor available" /40/;

parameter prices(drugs) / A 8, B 70, C 100/
          laborNeeds(drugs) / A 1, B 2, C 3/;

variable
         amt(drugs)      total amount of each drug produced
         saleable(drugs) amount of each drug available for sale
         sales           total dollar sales
;
positive variables amt, saleable;

* Why can't we define "sales" to be positive too?

equations
         laborConstraint total labor less than specified limit
         finalA          specifies amount of A available for sale
         finalB          specifies amount of B available for sale
         finalC          specifies amount of C available for sale
         objective       defines total sales
;

laborConstraint..
         sum(drugs, laborNeeds(drugs)*amt(drugs)) =e= labor;

finalA..
         saleable("A") =e= amt("A") - 2*amt("B");
finalB..
         saleable("B") =e= amt("B") - amt("C");
finalC..
         saleable("C") =e= amt("C");
objective..
         sales =e= sum(drugs, prices(drugs)*saleable(drugs));

model drugco /laborConstraint,finalA,finalB,finalC,objective/;

solve drugco using lp maximizing sales;

display saleable.l, sales.l;