$ondollar title  MoBrass (LP) Example 5.1 of Rardin (1998), with costs

* The data for this problem is similar to the topbrass example, except that:
*
* $12 and $9 represent the SELLING prices for the football and soccer trophies,
*    not the profit margin;
* There are additional costs: $1 for each boardfoot of wood used,
*                             $2 for each plaque
*                             $3 for each brass football
*                             $2 for each brass soccer ball
*

$offsymxref offsymlist offuelxref offuellist offupper
option limrow = 0, limcol = 0;

set I/football, soccer/
    J/wood, plaques/;

free variable profit "total profit";

positive variables
x(I) "trophies";

* DATA section

parameters
         sellingPrice(I) / football 12 , soccer 9 /
         maxBrass(I)     / football 1000, soccer 1500/
         costBrass(I)    / football 3, soccer 2/
         maxRaw(J)      max amt of raw materials / wood 4800, plaques 1750/
         costRaw(J)     cost per unit of raw materials / wood 1,    plaques 2/;

* table statement gives a convenient way to define a two-dimensional
* parameter "raw" which indicates the amount of raw materials needed
* to produce each manufactured item

table raw(I,J)
         wood     plaques
football    4           1
soccer      2           1;

* MODEL section

equations
obj    "max total profit"
typeBrass   "bound on the number of footballs and soccer balls used"
eqRaw   "bounds on the available amount of raw materials"
;

* profit is (total revenue) - (cost of raw materials) - (cost of brass items)

obj..
profit =e= sum(I, sellingPrice(I)*x(I))
           - sum((I,J), raw(I,J)*x(I)*costRaw(J))
           - sum(I, costBrass(I)*x(I));

* make sure that we don't use more than the maximum number of brass items
typeBrass(I)..
x(I) =l= maxBrass(I);

* make sure that we don't exceed the available raw materials
eqRaw(J)..
sum(I,raw(I,J)*x(I)) =l= maxRaw(J);

model mobrass /all/;

* SOLVE

solve mobrass using lp maximizing profit;